mirror of
https://codeberg.org/guix/guix.git
synced 2026-04-28 06:34:05 +00:00
76ac03cb0b
* guix/import/mix.scm: New file. * guix/import/mix/mix-lock.scm: New file. * guix/scripts/import/mix.scm: New file. * tests/import/mix.scm: New file. * Makefile.am (MODULES, SCM_TESTS): Register them. * etc/teams.scm (beam): Likewise. * gnu/packages/beam-apps.scm: New file. * gnu/packages/beam-packages.scm: New file. * gnu/packages/beam-sources.scm: New file. * gnu/local.mk (GNU_SYSTEM_MODULES): Register them. * etc/teams.scm (beam): Likewise. * guix/build-system/mix.scm (define-mix-inputs): New macro. (beam-name->package-name, hexpm-source, mix-inputs): New procedures. (mix-build): Add new variables. * guix/build/mix-build-system.scm (unpack-vendorize, symlink-vendorize, beam-package?): New procedures. (%standard-phases): Add new phases. (build, check, install): Add vendoring support. (%elixir-prefix, %beam-prefix, %vendorize-env-var): Add new symbols. (strip-prefix, package-name->elixir-name): Add support for beam-prefixed packages. * guix/scripts/import.scm (process-args): Add 'mix' importer. * etc/teams.scm (beam)<#:description>: Add Mix importer mention. * etc/teams.scm (beam)<#:scope>: Add "tests/import/hexpm.scm". * CODEOWNERS: Regenerate file. * guix/import/hexpm.scm (dependencies->package-names, hexpm->guix-package): Add optional mix-inputs support. * guix/scripts/import/hexpm.scm (show-help, %options, parse-options): Likewise. * tests/import/hexpm.scm: Likewise. * guix/import/hexpm.scm (hexpm->guix-package): Fix typo. * doc/guix.texi: Add initial documentation for mix importer and new option for hexpm importer. * doc/guix-cookbook.texi: Add example of packaging Elixir app. Change-Id: I5d11f8be111963fbac2fd6ab5fd0bd644f9488b0 Signed-off-by: Giacomo Leidi <therewasa@fishinthecalculator.me>
113 lines
3.8 KiB
Scheme
113 lines
3.8 KiB
Scheme
;;; GNU Guix --- Functional package management for GNU
|
||
;;; Copyright © 2020, 2022 Hartmut Goebel <h.goebel@crazy-compilers.com>
|
||
;;;
|
||
;;; This file is part of GNU Guix.
|
||
;;;
|
||
;;; GNU Guix is free software; you can redistribute it and/or modify it
|
||
;;; under the terms of the GNU General Public License as published by
|
||
;;; the Free Software Foundation; either version 3 of the License, or (at
|
||
;;; your option) any later version.
|
||
;;;
|
||
;;; GNU Guix is distributed in the hope that it will be useful, but
|
||
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;;; GNU General Public License for more details.
|
||
;;;
|
||
;;; You should have received a copy of the GNU General Public License
|
||
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
|
||
|
||
(define-module (guix scripts import hexpm)
|
||
#:use-module (guix ui)
|
||
#:use-module (guix utils)
|
||
#:use-module (guix scripts)
|
||
#:use-module (guix import hexpm)
|
||
#:use-module (guix scripts import)
|
||
#:use-module (srfi srfi-1)
|
||
#:use-module (srfi srfi-37)
|
||
#:use-module (srfi srfi-71)
|
||
#:use-module (ice-9 match)
|
||
#:use-module (ice-9 format)
|
||
#:export (guix-import-hexpm))
|
||
|
||
|
||
;;;
|
||
;;; Command-line options.
|
||
;;;
|
||
|
||
(define %default-options
|
||
'())
|
||
|
||
(define (show-help)
|
||
(display (G_ "Usage: guix import hexpm PACKAGE-NAME
|
||
Import and convert the hex.pm package for PACKAGE-NAME.\n"))
|
||
(display (G_ "
|
||
-h, --help display this help and exit"))
|
||
(display (G_ "
|
||
-V, --version display version information and exit"))
|
||
(newline)
|
||
(display (G_ "
|
||
-r, --recursive import packages recursively"))
|
||
(display (G_ "
|
||
-m, --mix-inputs use mix-inputs for input field"))
|
||
(newline)
|
||
(show-bug-report-information))
|
||
|
||
(define %options
|
||
;; Specification of the command-line options.
|
||
(cons* (option '(#\h "help") #f #f
|
||
(lambda args
|
||
(show-help)
|
||
(exit 0)))
|
||
(option '(#\V "version") #f #f
|
||
(lambda args
|
||
(show-version-and-exit "guix import hexpm")))
|
||
(option '(#\r "recursive") #f #f
|
||
(lambda (opt name arg result)
|
||
(alist-cons 'recursive #t result)))
|
||
(option '("mix-inputs") #f #f
|
||
(lambda (opt name arg result)
|
||
(alist-cons 'mix-inputs #t result)))
|
||
%standard-import-options))
|
||
|
||
|
||
;;;
|
||
;;; Entry point.
|
||
;;;
|
||
|
||
(define (guix-import-hexpm . args)
|
||
(define (parse-options)
|
||
;; Return the alist of option values.
|
||
(parse-command-line args %options (list %default-options)
|
||
#:build-options? #f))
|
||
|
||
(let* ((opts (parse-options))
|
||
(args (filter-map (match-lambda
|
||
(('argument . value)
|
||
value)
|
||
(_ #f))
|
||
(reverse opts))))
|
||
(match args
|
||
((spec)
|
||
(with-error-handling
|
||
(let ((name version (package-name->name+version spec)))
|
||
(if (assoc-ref opts 'recursive)
|
||
;; Recursive import
|
||
(map (match-lambda
|
||
((and ('package ('name name) . rest) pkg)
|
||
`(define-public ,(string->symbol name)
|
||
,pkg))
|
||
(_ #f))
|
||
(hexpm-recursive-import name version))
|
||
;; Single import
|
||
(let* ((mix-inputs (assoc-ref opts 'mix-inputs))
|
||
(sexp (hexpm->guix-package name #:version version
|
||
#:mix-inputs? mix-inputs)))
|
||
(unless sexp
|
||
(leave (G_ "failed to download meta-data for package '~a'~%")
|
||
spec))
|
||
sexp)))))
|
||
(()
|
||
(leave (G_ "too few arguments~%")))
|
||
((many ...)
|
||
(leave (G_ "too many arguments~%"))))))
|